SET ANSI_NULLS ON
SET QUOTED_IDENTIFIER ON
GO

IF OBJECT_ID(N'dbo.TF_Split', N'TF') IS NOT NULL
    DROP FUNCTION dbo.TF_Split;
GO

/**
author : doeyull.kim
e-mail : purumae@gmail.com
created date : 2009-07-10
description : 구분자를 가진 비 유니코드 문자열을 Split하여 테이블로 반환합니다.
**/

CREATE FUNCTION dbo.TF_Split (
	@vchString varchar(max),
	@vchDelimiter varchar(10)
)
RETURNS @tblResult table (string varchar(8000) NOT NULL)
AS
BEGIN
DECLARE @xmlString xml;

SET @xmlString = CAST(N'<X>' + REPLACE(@vchString, @vchDelimiter, '</X><X>') + '</X>' AS xml);

INSERT @tblResult (string)
SELECT N.value('.', 'varchar(8000)') FROM @xmlString.nodes('X') AS T(N)

RETURN;
END
GO

EXEC sp_addextendedproperty N'MS_Description', N'구분자를 가진 비 유니코드 문자열을 Split하여 테이블로 반환합니다.', N'user', N'dbo', N'function', N'TF_Split';
EXEC sp_addextendedproperty N'MS_Description', N'구분자를 포함한 비 유니코드 문자열.', N'user', N'dbo', N'function', N'TF_Split', N'parameter', N'@vchString';
EXEC sp_addextendedproperty N'MS_Description', N'구분자.', N'user', N'dbo', N'function', N'TF_Split', N'parameter', N'@vchDelimiter';
GO

IF OBJECT_ID(N'dbo.TF_NSplit', N'TF') IS NOT NULL
    DROP FUNCTION dbo.TF_NSplit;
GO

/**
author : doeyull.kim
e-mail : purumae@gmail.com
created date : 2008-07-10
description : 구분자를 가진 유니코드 문자열을 Split하여 테이블로 반환합니다.
**/

CREATE FUNCTION dbo.TF_NSplit (
	@nvcString nvarchar(max),
	@nvcDelimiter nvarchar(10)
)
RETURNS @tblResult table (string nvarchar(4000) NOT NULL)
AS
BEGIN
DECLARE @xmlString xml;

SET @xmlString = CAST(N'<X>'+REPLACE(@nvcString, @nvcDelimiter, N'</X><X>')+N'</X>' AS xml);

INSERT @tblResult (string)
SELECT N.value(N'.', 'nvarchar(4000)') FROM @xmlString.nodes(N'X') AS T(N)

RETURN;
END
GO

EXEC sp_addextendedproperty N'MS_Description', N'구분자를 가진 유니코드 문자열을 Split하여 테이블로 반환합니다.', N'user', N'dbo', N'function', N'TF_NSplit';
EXEC sp_addextendedproperty N'MS_Description', N'구분자를 포함한 유니코드 문자열.', N'user', N'dbo', N'function', N'TF_NSplit', N'parameter', N'@nvcString';
EXEC sp_addextendedproperty N'MS_Description', N'구분자.', N'user', N'dbo', N'function', N'TF_NSplit', N'parameter', N'@nvcDelimiter';
GO